【Edge活用】新規ウィンドウで開くショートカットを作成するVBScriptサンプル

今回の記事では、指定したURLを、Microsoftの標準ブラウザである「Edge」の新規ウィンドウで開くショートカットを作成するスクリプトを紹介します。

尚、当記事では紹介するスクリプトはVBScriptを使用して記述しております。
よって、テキストファイルに当記事のコードを貼り付けて、文字コードをSJISに変更しつつ、ファイルの拡張子をvbsに変更して保存していただければ動作します。

パソコンのセットアップ自動化や管理端末に対するスクリプト配信などで是非ご活用ください。
 

当ブログの過去記事の解説

今回作成したサンプルコードは、当記事で過去に公開した幾つかの記事内容を参考にしていただければ作れます。
ただ、Edgeの実行ファイルの場所を動的に取得したうえで、その実行ファイルのパスを指定してEdgeを新規ウィンドウで開くショートカットをデスクトップに作りたいという需要はありそうなので、一つの記事にしてみました。

過去の記事のリンクも貼っておきます。

【Microsoft Edge】新Edgeのショートカットを別ウィンドウで開く方法

皆様の会社のパソコンのデスクトップには、社内で使用するWebベースのグループウェアや業務システムのショートカットが置いて...

www.depthbomb.net

2020.09.12

Edgeのインストール先はどこ？実行ファイルの場所を取得できるレジストリとサンプルコード

先日、Microsoftの標準ブラウザである「Edge」のインストール先(実行ファイルの場所)をコマンドやスクリプトから...

www.depthbomb.net

2022.06.09

【VBScript】情シス必見！レジストリを編集してIEの設定作業を自動化

今回はVBScrptからレジストリを編集し、IEの設定を自動化する方法を紹介します。 ※レジストリをWindowsの各...

www.depthbomb.net

2020.06.25

Edgeを新規ウィンドウで開くショートカットを作成するサンプルコード

処理としては以下の流れです。

1. 特定のレジストリの参照し、msedge.exeのパスを取得します。
2. 上記1.で取得したパスを元にデスクトップにショートカットを作成する。

サンプルではGoogleへのリンクとYahooへのリンクを作成し、Googleへのリンクは「新規ウィンドウ」でEdgeを開き、Yahooへのリンクは「新規タブ」でEdgeを開くように実装しております。

  Option Explicit
  Const RegKey = "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\msedge.exe\Path"
  Dim objShell
  Dim objShortCut
  Dim Desktop_Path
  Dim ShortCutName
  Dim EdgeExe_Path
  Dim objFS
  Dim RegVal

      RegVal = ""

      Set objShell = WScript.CreateObject("WScript.Shell")
      Desktop_Path = objShell.SpecialFolders("Desktop")
      Set objFS = CreateObject("Scripting.FileSystemObject")

      On Error Resume Next
          'HKCU配下のレジストリの読み取りを試行します。
          RegVal = objShell.RegRead("HKEY_CURRENT_USER\" & RegKey)
          Err.Clear
          '値が空なら対象のレジストリキーが存在しないと判定して次を試行します。
          If RegVal = "" Then    
              RegVal = objShell.RegRead("HKEY_LOCAL_MACHINE\" & RegKey)
          End If
          Err.Clear
      On Error GoTo 0

      If RegVal = "" Then
          Msgbox "Edge がインストールされていません。" & vbCrlf & "処理を中止します。"
          Wscript.Quit
      End If

      EdgeExe_Path = RegVal & "\msedge.exe"

      'Edgeがインストールされているかを確認します。
      If objFS.FileExists(EdgeExe_Path) Then

          '■Edgeのexeを指定したショートカットを作成します。
          'Google
          '作成するショートカットの名前を指定します。
          ShortCutName = Desktop_Path & "\Googleショートカット_edge新規ウィンドウ.lnk"
          Set objShortCut = objShell.CreateShortcut(ShortCutName)
          'ショートカットの実行ファイルの場所を指定します。
          objShortCut.TargetPath = EdgeExe_Path
          '作業フォルダを指定します。
          objShortCut.WorkingDirectory = "%USERPROFILE%\Desktop" 
          '対象のEXEに渡す引数を指定します。
          objShortCut.Arguments = "--new-window  ""https://www.google.com/"""
          '定義した内容でショートカットを保存します。
          objShortCut.Save

          'Yahoo※新規タブで開く場合
          '作成するショートカットの名前を指定します。
          ShortCutName = Desktop_Path & "\Yahooショートカット_edge新規ウィンドウ.lnk"
          Set objShortCut = objShell.CreateShortcut(ShortCutName)
          'ショートカットの実行ファイルの場所を指定します。
          objShortCut.TargetPath = EdgeExe_Path
          '作業フォルダを指定します。
          objShortCut.WorkingDirectory = "%USERPROFILE%\Desktop" 
          '対象のEXEに渡す引数を指定します。
          objShortCut.Arguments = """https://www.yahoo.co.jp/"""
          '定義した内容でショートカットを保存します。
          objShortCut.Save

          Set objShortCut = Nothing
      Else
  	    Msgbox "Edge がインストールされていません。" & vbCrlf & "処理を中止します。"
      End If
      Set objShell = Nothing
      Set objFS = Nothing

最後に

今回は、Edgeの新規ウィンドウで指定したURLを開くショートカットを作成するスクリプトを紹介させていただきました。
IEのサポートも終了し、業務システムなどで使われるブラウザをEdgeに切り替えている企業も多いかと思いますが、今回紹介したスクリプトも上手く活用していただければと思います。
今回も読んでいただきありがとうございました。
それでは皆さまご機嫌よう！